MQL5 Wizard – Trade Signals Based on Hammer/Hanging Man + Stochastic – EA MetaTrader 5

The MQL5 Wizard allows creating ready-made Expert Advisors based on the Standard library classes delivered together with the client terminal (see Creating Ready-Made Expert Advisors in MQL5 Wizard for the details). It allows to check your trade ideas quickly, all you need is to create your own trading signals class. The structure of this class and example can be found in the article MQL5 Wizard: How to Create a Module of Trading Signals.

The generic idea is the following: the class of trading signals is derived from CExpertSignal, the next, it’s necessary to override the LongCondition() and ShortCondition() virtual methods with your own methods.

There is a book “Strategies of best traders” (in Russian), there are many trading strategies are considered there, we will focus on reversal candlestick patterns, confirmed by Stochastic, CCI, MFI and RSI oscillators.

The best way is to create the separate class, derived from CExpertSignal for checking of formation of candlestick patterns. For confirmation of trade signals, generated by candlestick patterns, it’s sufficient to write the class, derived from CCandlePattern and add the necessary features (for example, confirmation by oscillators) there.

Here we will consider the signals, based on “Hammer/Hanging Man” reversal candlestick pattern, confirmed by Stochastic indicator. The module of trade signals is based on the CCandlePattern class, it’s simple example of its use for creation of trade signals with candlestick patterns.

1. “Hammer” and “Hanging Man” reversal candlestick patterns

1.1. Hammer

The “Hammer” is a candlestick with a small body and long lower wick, formed after downward price movement. The “Hammer” pattern indicates the end of a bearish trend.

The color of a candlestick body isn’t important, but bullish hammer indicates higher bullish potential. The body of the “Hammer” pattern often formed near the mininum of the previous candle. The longer lower wick and shorter upper wick leads to higher potential of the reversal pattern.

Fig. 1. “Hammer” candlestick pattern

The recognition of “Hammer” pattern is implemented in CheckPatternHammer() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Hammer" candlestick pattern                 |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- Hammer
   if((MidPoint(1)<CloseAvg(2))                                 && // down trend
      (MathMin(Open(1),Close(1))>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // body gap
      return(true);
//---
   return(false);
  }

1.2. Hanging Man

The “Hanging Man” is a candlestick with a small body and long lower wick, formed after upward price movement. The “Hanging Man” pattern indicates the end of a bullish trend.

The color of a candlestick body isn’t important, but bearish candle indicates higher bearish potential. The body of the “Hanging Man” pattern often formed near the maxinum of the previous candle. The longer lower wick and shorter upper wick leads to higher potential of the reversal pattern.

Figure 2. “Hanging Man” candlestick pattern

The recognition of “Hanging Man” pattern is implemented in CheckPatternHangingMan() method of CCandlePattern class:

//+------------------------------------------------------------------+

//| Checks formation of "Hanging Man
" candlestick pattern            |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- Hanging man
   if((MidPoint(1)>CloseAvg(2))                                && // up trend
      (MathMin(Open(1),Close(1)>(High(1)-(High(1)-Low(1))/3.0)) && // body in upper 1/3
      (Close(1)>Close(2)) && (Open(1)>Open(2))))                  // body gap
      return(true);
//---
   return(false);
  }

2. Trade signals, confirmed by Stochastic indicator

The trading signals to open long or short position must be confirmed by Stochastic oscillator. The signal %D line must be greater/lower then corresponding critical level (30 or 70).

The closing of opened position depends on the values of %D indicator. It can be done in 2 cases:

1. if %D line has reached the opposite critical level (80 for long position and 20 for short position)
2. if the reverse signal isn’t confirmed (when %D line reaches the following levels: 20 for long position and 80 for short position)

Figure 3. “Hammer” pattern, confirmed by Stochastic indicator

• int CH_HM_Stoch::LongCondition() – checks conditions to open long position (returns 80) and close of the short position (returns 40);
  
• int CH_HM_Stoch::ShortCondition() – checks conditions to open short position (returns 80) and close of the long position (returns 40).

2.1. Open long position/Close short position

1. The formation of “Hammer” pattern must be confirmed by Stochastic indicator: StochSignal(1)<30 (the value of the signal line of Stochastic indicator of the last completed bar must be less than 30).

2. The short position must be closed if the signal line of Stochastic indicator has crossed upward the 20 or 80 levels.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CH_HM_Stoch::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Hammer pattern and signal line<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (StochSignal(1)<30))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward 20, upward 80)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- return result
   return(result);
  }

2.2. Open short position/Close long position

1. The formation of “Hanging Man” pattern must be confirmed by Stochastic indicator: StochSignal(1)>70 (the value of the signal line of Stochastic indicator of the last completed bar must be greater than 70).

2. The long position must be closed if the signal line of Stochastic indicator has crossed downward the 80 or 20 levels.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CH_HM_Stoch::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Hanging Man pattern and signal line>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (StochSignal(1)>70))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward 80, upward 20)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- return result
   return(result);
  }

2.3. Creating Expert Advisor using MQL5 Wizard

To create an Expert Advisor launch MQL5 Wizard:

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Let’s specify the name of the Expert Advisor:

Fig. 5. General properties of the Expert Advisor

After that we need to select the modules of trade signals used.

Fig. 6. Signal properties of the Expert Advisor

In our case we use only one module of trade signals.

Adding the “Signals based on Hammer/Hanging Man confirmed by Stochastic” module of trading signals:

Fig. 7. Signal properties of the Expert Advisor

Module of trade signals added:

Fig. 8. Signal properties of the Expert Advisor

You can select any trailing properties, but we will use “Trailing Stop not used”:

Fig. 9. Trailing properties of the Expert Advisor

Concerning the money management properties, we will use “Trading with fixed trade volume”:

Fig. 10. Money management properties of the Expert Advisor

By pressing the “Finish” button, we will get the code of the generated Expert Advisor, located in Expert_AH_HM_Stoch.mq5, it will be saved in terminal_data_folder\MQL5\Experts\.

The default input parameters of the generated Expert Advisor:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in points)

must be replaced to:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

The Signal_ThresholdOpen/Signal_ThresholdClose input parameters allow to specify threshold levels for open and close of positions.

In code of the LongCondition() and ShortCondition() methods of the trade signals class we have specified the fixed values of the threshold:

• Open position: 80;
• Close position: 40.
  

The values of  Signal_StopLevel and Signal_TakeLevel input parameters is set to 0, it means that closing of the positions will be done only when closing conditions will be true.

2.4. History backtesting results

Let’s consider backtesting of the Expert Advisor on historical data (EURUSD H1, testing period: 2010.01.01-2011.03.04, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5).

In creation of Expert Advisor we used the fixed volume (Trading Fixed Lot, 0.1), Trailing Stop algorithm is not used (Trailing not used).

Fig. 11. Testing results of the Expert Advisor, based on Hammer/Hanging Man + Stochastic”

The best set of input parameters can be found using the Strategy Tester of MetaTrader 5 client terminal.

The code of the Expert Advisor, created by MQL5 Wizard is attached in expert_ah_hm_stoch.mq5.